4P1L triode SPICE model

After playing for some time with Dmitry’s great DHT composite triode models, I looked at refining the model by matching my own set of curves of the 4P1L in triode-mode. Here is my take on it:

And here is the SPICE model:

*** 4P1L TRIODE ******************************************
* Created on 04/01/2013 10:53 using paint_kit.jar
* www.bartola.co.uk/valves / [email protected]
* Created by Ale Moglia from curve tracer
* Curves image file: 4P1L Triode.jpg
* Data source link: www.bartola.co.uk/valves
*----------------------------------------------------------------------------------
.SUBCKT TRIODE_4P1L 1 2 3 4; Plate Grid K1 K2
+ PARAMS: CCG=3P CGP=4P CCP=2P
+ MU=8.16 KG1=1702 KP=124
+ KVB=533 VCT=0 EX=1.59 RGI=2000
* Vp_MAX=500 Ip_MAX=0.08
* Vg_step=5 Vg_start=5 Vg_count=11
* END PARAMS -----------------------------------------------------------------------
* cathode resistor is (2.1V/650ma) = 3.23 ohm, the pins K1 and K2 are 0.807 ohms from the ends of it
RFIL_LEFT 3 31 0.807
RFIL_RIGHT 4 41 0.807
RFIL_MIDDLE 31 41 1.615
E11 32 0 VALUE={V(1,31)/KP*LOG(1+EXP(KP*(1/MU+V(2,31)/SQRT(KVB+V(1,31)*V(1,31)))))}
E12 42 0 VALUE={V(1,41)/KP*LOG(1+EXP(KP*(1/MU+V(2,41)/SQRT(KVB+V(1,41)*V(1,41)))))}
RE11 32 0 1G
RE12 42 0 1G
G11 1 31 VALUE={(PWR(V(32),EX)+PWRS(V(32),EX))/(2*KG1)}
G12 1 41 VALUE={(PWR(V(42),EX)+PWRS(V(42),EX))/(2*KG1)}
RCP1 1 3 1G
RCP2 1 4 1G
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
D4 6 4 DX ; FOR GRID CURRENT
RG1 2 5 {RGI} ; FOR GRID CURRENT
RG2 2 6 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$

Note that the above triode is with paralleled filaments so it’s running at 2.1V and 650mA. Also this model use the 4-element DHT symbol in SPICE.

Looking at Dmitry’s parameters on his model:

*-------------------------------------------------------------------------------
* TRIODE_4P1L_COMPOSITE_5: Russian pentode 4P1L in triode mode.
* Five-element Composite model.
* Created on Wed Mar 16 22:56:00 PST 2005 using tube.model.finder.PaintKIT
* tube data: http://www.klausmobile.narod.ru/testerfiles/4p1l.htm
* http://www.klausmobile.narod.ru/testerfiles/4p1l_vah_10.gif
*-------------------------------------------------------------------------------
.SUBCKT TRIODE_4P1L_COMPOSITE_5 1 2 3 4 ; P G K1 K2
XDHT 1 2 3 4 DHT_COMPOSITE_5
+ PARAMS: CCG=3P CGP=4P CCP=2P RGI=2000 RFILQ=1
+ MU=9.88 EX=1.4 KG1=914 KP=101 KVB=168.5 VCT=0.003 ; Vp_MAX=175.0 Ip_MAX=0.04 Vg_step=2.0
.ENDS
*$

We can see that there is a difference in KP which makes both model to perform different from a linearity point of view. Highly linear triodes have KP above 100. Here are some examples:

Despite having a minor difference of 20 (KP=101 – Dmitry’s and KP=121 – Ale’s model)  I found that the models behave differently when driving large signals. The impact of KP is more evident at those extremes of the curves and my model provides a more linear 4P1L representation.

Here is a typical loadline for a 5k6 OT:

 

Are you looking for a PSE Spice model? I’ve done my version here by simply doubling the anode current (from 80mA to 160mA maximum) and halving KP parameter:

Also note that Pa is now doubled to 18W maximum.

Here is the 4-element SPICE composite model:

**** 4P1LPSE ******************************************
* Created on 03/23/2013 08:47 using paint_kit.jar
* www.bartola.co.uk/valves
* Curves image file: 4P1LPSE
* Data source link: 4P1LPSE
*----------------------------------------------------------------------------------
.SUBCKT TRIODE_4P1LPSE 1 2 3 4 ; Plate Grid K1 K2
+ PARAMS: CCG=6P CGP=8P CCP=4P
+ MU=8.16 KG1=851 KP=124
+ KVB=533 VCT=0 EX=1.57 RGI=2000
* Vp_MAX=550 Ip_MAX=0.16
* Vg_step=5 Vg_start=5 Vg_count=14
* END PARAMS -----------------------------------------------------------------------
* cathode resistor is (2.1V/(2x650ma) = 1.615 ohm, the pins K1 and K2 are 0.403 ohms from the ends of it
RFIL_LEFT 3 31 0.403
RFIL_RIGHT 4 41 0.403
RFIL_MIDDLE 31 41 0.807
E11 32 0 VALUE={V(1,31)/KP*LOG(1+EXP(KP*(1/MU+V(2,31)/SQRT(KVB+V(1,31)*V(1,31)))))}
E12 42 0 VALUE={V(1,41)/KP*LOG(1+EXP(KP*(1/MU+V(2,41)/SQRT(KVB+V(1,41)*V(1,41)))))}
RE11 32 0 1G
RE12 42 0 1G
G11 1 31 VALUE={(PWR(V(32),EX)+PWRS(V(32),EX))/(2*KG1)}
G12 1 41 VALUE={(PWR(V(42),EX)+PWRS(V(42),EX))/(2*KG1)}
RCP1 1 3 1G
RCP2 1 4 1G
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
D4 6 4 DX ; FOR GRID CURRENT
RG1 2 5 {RGI} ; FOR GRID CURRENT
RG2 2 6 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$

And here is a typical loadline with a 5k6 OT gapped at 60mA:

Hope you enjoy it!