Thanks to the great work that Derk put into his great Extract Model tool, I helped him to refine and debug the application by tracing the challenging 6e5p beam tetrode. After 4 versions we managed to optimise the model:
The model fits really well including the kink section but given the saturation of the 6e5p tetrode at currents above 50mA there is a slight divergence as the valve cannot reach the same anode current at higher voltages.
The recommendations to generate more accurate results with this tool include:
- Average measurements as much as you can (I’ve been lazy this time!)
- Take 50-60 points per data set. Try to get full anode voltage span where possible in pentode mode.
- Triode curves should not reveal saturation or will provide wrong fit which will impact the pentode model generation effectiveness
- Take 3-4 Vg curves per Vs with a view of capturing representative data sets like x4 x5 variance in anode current where possible.
- Very small Ia values are converted to 0mA by uTracer and will lead to overflow runtime errors. Derk is looking at fixing this. In the meantime avoid tracing low anode currents
Here is the model for your test:
****************************************************
.SUBCKT 6e5p-tetrode-150V 1 2 3 4 ; A G2 G1 C;
* Extract V1.032
* Model created: 26-Jan-2014
* Trace and model by Ale Moglia [email protected] using uTracer v3 and ExtractTool
X1 1 2 3 4 BTetrodeDE MU= 31.86 EX=1.879 kG1= 99.6 KP= 461.2 kVB = .0 kG2= 627.2
+Sc=.11E-01 ap= .018 w= -11. nu= 11.90 lam= 3.57
+ Ookg1mOokG2=.845E-02 Aokg1=.61E-05 alkg1palskg2=.845E-02 be= .043 als= 4.78 RGI=2000
+ CCG1=15.0P CCG2 = 0.0p CPG1 = 0.065p CG1G2 = 0.0p CCP=2.55P ;
.ENDS****************************************************
.SUBCKT BTetrodeDE 1 2 3 4; A G2 G1 C
RE1 7 0 1MEG ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1 7 0 VALUE=
+{V(2,4)/KP*LOG(1+EXP(KP*(1/MU+V(3,4)/SQRT(KVB+V(2,4)*V(2,4)))))}
E2 8 0 VALUE = {Ookg1mOokG2 + Aokg1*V(1,4) – alkg1palskg2*Exp(-be*V(1,4)*SQRT(be*V(1,4)))}
E3 9 0 VALUE = {Sc/kG2*V(1,4)*(1+tanh(-ap*(V(1,4)-V(2,4)/lam+w+nu*V(3,4))))}
G1 1 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))*(V(8)-V(9))}
G2 2 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG2 *(1+als*Exp(-be*V(1,4) * SQRT(be*V(1,4))))}
RCP 1 4 1G ; FOR CONVERGENCE A – C
C1 3 4 {CCG1} ; CATHODE-GRID 1 C – G1
C4 2 4 {CCG2} ; CATHODE-GRID 2 C – G2
C5 2 3 {CG1G2} ; GRID 1 -GRID 2 G1 – G2
C2 1 3 {CPG1} ; GRID 1-PLATE G1 – A
C3 1 4 {CCP} ; CATHODE-PLATE A – C
R1 3 5 {RGI} ; FOR GRID CURRENT G1 – 5
D3 5 4 DX ; FOR GRID CURRENT 5 – C
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS BTetrodeDE
