6F12P a great Russian valve

The 6F12P is used (by many) in Europe (mainly) in RIAA circuit. You would wonder why? Well, it’s a great Russian frame-pentode which has high-mu and high-gm therefore driving larger currents at low distortion.

Recently, Anatoliy Lisovskiy from Wavebourn posted this great summary review on Russian valves which made me immediately connect and look on my files. I had traced, experimented a lot with this valve before using it on some RIAA designs:

The history of tubes:
1. 6S19P triodes were designed for military power supplies as pass regulators. They have low internal resistance, and because they are long for power dissipation, they also are very linear. Grids are relatively far from cathodes, so they need high voltage swing to drive them, and pretty good current due to capacitances. But they are happy in A1 mode, don’t need A2 drive like other triodes like 300B, for example.
2. Gu-17 tube was copied after QQE 03/12 to work in UHF transmitters. It contain 2 tetrodes per bulb. Electrodes are long, so it can produce high linear swing when used as a LTP.
3. 6F12P is a frame grid pentode-triode. It has both high mu and high gm, unlike 12AX7 that has low gm, or 12AU7 that has low mu. As the result, amplification stages with such tube have amplification like 12AX7, but faster, like 12AU7, and can provide higher load current with lower distortions. Frame grid tubes were designed at the end of a vacuum tube era, in the quest for better linearity.
Military QC diamond stamps look ugly, though…

Anatoliy Lisovskiy – Wavebourn.com

Triode Section

The triode section has lower total input capacitance than the pentode. Yet, at about 420pF is too high for most of MM cartridges. For RIAA stage, I’d use a folded cascode first stage with a jFET using Rod Coleman’s circuit. It works brilliantly. You can split the RIAA constant between first stage and the second (using a 6F12P) and finally a cathode follower with the remaining triode of the 6F12P.

In summary, the triode section of the 6F12P has:

Mu is about 100. Gain should be maximum 40dB
total input capacitance measured is 418pF @gain of 40.5dB (x106)
From data sheet Cgk=4.6pF. Given Cin=Cgk+(mu+1)*Cag -> Cag = (Cin-Cgk)/(mu+1) = 3.86pF

Updated LT spice 6F12P-triode1-model below

**** 6FF12P_TRIODE1 ******************************************
* Created on 06/12/2016 11:08 using paint_kit.jar 2.9
* www.dmitrynizh.com/tubeparams_image.htm
* Plate Curves image file: 6FF12P-triode1.png
* Data source link:
*
* Traced and model developed by Ale Moglia [email protected]
* www.bartola.co.uk/valves
*
* 1. total input capacitance measured is 418pF @gain of 40.5dB (x106)
* 2. From data sheet Cgk=4.6pF.  Given Cin=Cgk+(mu+1)*Cag -> Cag = (Cin-Cgk)/(mu+1) = 3.86pF
*----------------------------------------------------------------------------------

.SUBCKT TRIODE_6FF12P-1 1 2 3 ; Plate Grid Cathode
+ PARAMS: CCG=4.6P  CGP=3.86P CCP=0.26P RGI=2000
+ MU=100 KG1=165 KP=768 KVB=66 VCT=0.188 EX=1.44
* Vp_MAX=200 Ip_MAX=30 Vg_step=0.2 Vg_start=0 Vg_count=10
* Rp=4000 Vg_ac=55 P_max=40 Vg_qui=-48 Vp_qui=300
* X_MIN=75 Y_MIN=51 X_SIZE=371 Y_SIZE=497 FSZ_X=1072 FSZ_Y=683 XYGrid=false
* showLoadLine=n showIp=y isDHT=n isPP=n isAsymPP=n showDissipLimit=y
* showIg1=n gridLevel2=n isInputSnapped=n  
* XYProjections=n harmonicPlot=n harmonics=y
*----------------------------------------------------------------------------------
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G  ; TO AVOID FLOATING NODES
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G   ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; POSITIVE GRID CURRENT
R1 2 5 {RGI} ; POSITIVE GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$

Pentode Section (triode strapped)

Mu is about 87. Gain should be maximum 38-39dB
total input capacitance measured is 605pF @gain of 39dB (x89.1)
From data sheet Cgk=6.6pF. Given Cin=Cgk+(mu+1)*Cag -> Cag = (Cin-Cgk)/(mu+1) = 6.64pF

The pentode triode-strapped LTSpice 6F12P triode2 model below:

**** 6F12P TRIODE2 pentode section triode strapped ******************************************
* Created on 06/12/2016 11:21 using paint_kit.jar 2.9
* www.dmitrynizh.com/tubeparams_image.htm
* Plate Curves image file: 6F12P triode2.png
* Data source link:
* PENTODE Section (triode strapped)
* Traced and model developed by Ale Moglia [email protected]
* www.bartola.co.uk/valves
*
* 1. total input capacitance measured is 605pF @gain of 39dB (x89.1)
* 2. From data sheet Cgk=6.6pF.  Given Cin=Cgk+(mu+1)*Cag -> Cag = (Cin-Cgk)/(mu+1)  =6.64pF
*
*----------------------------------------------------------------------------------
.SUBCKT TRIODE_6F12P-2 1 2 3 ; Plate Grid Cathode
+ PARAMS: CCG=6.6P  CGP=6.64P CCP=1.9P RGI=2000
+ MU=86.9 KG1=120 KP=512 KVB=435 VCT=0.228 EX=1.2
* Vp_MAX=200 Ip_MAX=40 Vg_step=0.2 Vg_start=0 Vg_count=10
* Rp=4000 Vg_ac=55 P_max=40 Vg_qui=-48 Vp_qui=300
* X_MIN=76 Y_MIN=50 X_SIZE=630 Y_SIZE=516 FSZ_X=1333 FSZ_Y=664 XYGrid=false
* showLoadLine=n showIp=y isDHT=n isPP=n isAsymPP=n showDissipLimit=y
* showIg1=n gridLevel2=n isInputSnapped=n  
* XYProjections=n harmonicPlot=n harmonics=y
*----------------------------------------------------------------------------------
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G  ; TO AVOID FLOATING NODES
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G   ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; POSITIVE GRID CURRENT
R1 2 5 {RGI} ; POSITIVE GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$

Pentode Section (triode strapped) performance

Just be careful given the transconductance of this valve, if you don’t put the screen and gate stoppers it oscillates widely.

Here is the response of the pentode section, again 39-40dB of gain expected:

6F12P pentode triode strapped: 2V output @ 0.0185% THD

6F12P pentode triode strapped: 10V output at 0.084% THD

Triode Section performance

6F12P triode with gyrator load and DC-coupled to Source Follower

The interesting aspect of this valve is that you can still have a wide BW (up to 100kHz) without the source follower. If this valve is going to be used as a gain stage in a RIAA, then is better to avoid the SF from a noise point of view unless this is the last stage of the RIAA and you need to drive longer cables. In that scenario, the above configuration is the best solution.

6F12P triode: 0.015% THD @ 10Vrms output

In summary, a great valve which is perfect for a RIAA stage. Very linear (as seen on the above measurements) and with sufficient gain to work well in a pre-amplifier topology.