D3a Pentode

Traced curves of a Siemens sample measuring 103%:

D3a Triode Curves

Pentode curves:

Spice Model

Here’s the model fit using Derk’s tool:

D3a pentode model fit
D3a triode model fit

And the triode and pentode models. They can be downloaded here: D3a-Triode , D3a-Pentode-100V

****************************************************

.SUBCKT D3a-Pentode-100V 1 2 3 4 ; A G2 G1 C;

*      Extract V3.000

* Model created: 10-Jun-2020

*

* Curves traced and model developed by Ale Moglia

* (c) 2020 Bartola Valves

* www.bartola.co.uk/valves email: [email protected]

*

*

X1 1 2 3 4 PenthodeDE  MU= 77.9 EX=1.433 kG1=  25.7 KP= 587.2 kVB =  2940.0 kG2=  106.5

+ Ookg1mOokG2=.29E-01 Aokg1=.13E-04 alkg1palskg2=.29E-01 be=  .049 als=  2.57 RGI=2000

+ CCG1=6.8P  CCG2 = 0.0p CPG1 = 0.04p  CG1G2 = 9.5p CCP=0.05P  ;

.ENDS

****************************************************

.SUBCKT PenthodeDE 1 2 3 4; A G2 G1 C

*

* NOTE: LOG(x) is base e LOG or natural logarithm.

* For some Spice versions, e.g. MicroCap, this has to be changed to LN(x).

*

RE1  7 0  1MEG    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS

E1 7 0 VALUE=

+{V(2,4)/KP*LOG(1+EXP(KP*(1/MU+V(3,4)/SQRT(KVB+V(2,4)*V(2,4)))))}

E2   8 0 VALUE = {Ookg1mOokG2 + Aokg1*V(1,4) – alkg1palskg2*Exp(-be*V(1,4)*SQRT(be*V(1,4)))}

G1   1 4  VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))*V(8)}

G2   2 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG2 *(1+als*Exp(-be*V(1,4) * SQRT(be*V(1,4))))}

RCP  1 4  1G      ; FOR CONVERGENCE A  – C

C1   3 4  {CCG1}   ; CATHODE-GRID 1 C  – G1

C4   2 4  {CCG2}   ; CATHODE-GRID 2 C  – G2

C5   2 3  {CG1G2}   ; GRID 1 -GRID 2 G1  – G2

C2   1 3  {CPG1}  ; GRID 1-PLATE G1 – A

C3   1 4  {CCP}   ; CATHODE-PLATE A  – C

R1   3 5  {RGI}   ; FOR GRID CURRENT G1 – 5

D3   5 4  DX      ; FOR GRID CURRENT 5  – C

.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)

.ENDS PenthodeDE

And triode:

****************************************************
.SUBCKT D3a-Triode 1 2 3; A G C;
* Extract V3.000
* Model created: 10-Jun-2020
*
*
* Curves traced and model developed by Ale Moglia
* (c) 2020 Bartola Valves
* www.bartola.co.uk/valves email: [email protected]
*
*
X1 1 2 3 TriodeK MU= 77.92 EX=1.515 KG1= 25.7 KP= 587.2 KVB= 2940. RGI=2000
+ CCG=6.7P CGP=3.3P CCP=1.0P ;
.ENDS

****************************************************
.SUBCKT TriodeK 1 2 3; A G C
*
* NOTE: LOG(x) is base e LOG or natural logarithm.
* For some Spice versions, e.g. MicroCap, this has to be changed to LN(x).
*
E1 7 0 VALUE=
+{V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS TriodeK